const std = @import("std");

pub fn main() !void {
    const input = @embedFile("2.txt");
    try std.fmt.format(std.io.getStdOut().writer(), "{}\n", .{try run(input)});
}

test {
    const value = try run(
        \\7 6 4 2 1
        \\1 2 7 8 9
        \\9 7 6 2 1
        \\1 3 2 4 5
        \\8 6 4 4 1
        \\1 3 6 7 9
    );
    std.debug.print("got {}\n", .{value});
    std.debug.assert(value == 4);
}

pub fn run(input: []const u8) !u32 {
    var lines = std.mem.split(u8, input, "\n");

    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
    defer arena.deinit();
    const allocator = arena.allocator();

    var reports = std.ArrayList(std.ArrayList(u32)).init(allocator);
    defer reports.deinit();

    while (lines.next()) |line| {
        if (line.len == 0) continue;
        var report = std.ArrayList(u32).init(allocator);
        var words = std.mem.split(u8, line, " ");
        while (words.next()) |word| {
            try report.append(try std.fmt.parseInt(u32, word, 10));
        }
        try reports.append(report);
    }

    var safe: u32 = 0;
    for (reports.items) |report| {
        var is_safe = false;
        for ([_]bool{ false, true }) |increasing| for (0..report.items.len) |skipped| {
            const first: u32 = if (skipped == 0) 1 else 0;
            var prev = report.items[first];
            for (first + 1..report.items.len) |i| {
                if (i == skipped) continue;
                const curr = report.items[i];
                if ((prev < curr) != increasing or prev == curr or @max(prev, curr) - @min(prev, curr) > 3) {
                    break;
                }
                prev = curr;
            } else {
                is_safe = true;
            }
        };
        if (is_safe) safe += 1;
        // std.debug.print("{any} is {s}safe\n", .{ report.items, if (is_safe) "" else "un" });
    }

    return safe;
}